949e878ffb
variable, allowing it to be overridden during make. svn path=/trunk/; revision=4697
754 lines
19 KiB
Text
754 lines
19 KiB
Text
# $Id: configure.in,v 1.153 2002/02/05 18:39:05 gram Exp $
|
|
dnl
|
|
dnl Process this file with autoconf 2.13 or later to produce a
|
|
dnl configure script; 2.12 doesn't generate a "configure" script that
|
|
dnl defines SHELL, and "Makefile.in" has
|
|
dnl
|
|
dnl SHELL = @SHELL@
|
|
dnl
|
|
dnl which requires it to be defined - and there may be other problems
|
|
dnl with pre-2.13 "autoconf" as well.
|
|
dnl
|
|
AC_INIT(etypes.h)
|
|
|
|
AC_PREREQ(2.13)
|
|
|
|
AM_INIT_AUTOMAKE(ethereal, 0.9.1)
|
|
|
|
dnl Check for CPU / vendor / OS
|
|
AC_CANONICAL_HOST
|
|
|
|
dnl Checks for programs.
|
|
AC_PROG_CC
|
|
AC_PROG_CPP
|
|
AC_PROG_RANLIB
|
|
AC_PROG_YACC
|
|
AM_PROG_LEX
|
|
AC_PATH_PROG(PERL, perl)
|
|
AC_PATH_PROG(POD2MAN, pod2man)
|
|
AC_PATH_PROG(LEX, flex)
|
|
AC_PATH_PROG(PYTHON, python)
|
|
|
|
AC_SUBST(PERL)
|
|
AC_SUBST(LEX)
|
|
AC_SUBST(PYTHON)
|
|
|
|
# Check for packaging utilities
|
|
# For now, we check to see if the various packaging utilites are in our
|
|
# path. I'm too lazy to write code to go hunt for them. - Gerald
|
|
AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
|
|
AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
|
|
AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
|
|
|
|
if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
|
|
-a x$HAVE_PKGTRANS = xyes ; then
|
|
HAVE_SVR4_PACKAGING=yes
|
|
else
|
|
HAVE_SVR4_PACKAGING=no
|
|
fi
|
|
AC_SUBST(HAVE_SVR4_PACKAGING)
|
|
|
|
AC_ETHEREAL_RPM_CHECK
|
|
AC_SUBST(HAVE_RPM)
|
|
|
|
# If we're running gcc, add '-Wall' to CFLAGS.
|
|
AC_MSG_CHECKING(to see if we can add '-Wall' to CFLAGS)
|
|
if test x$GCC != x ; then
|
|
CFLAGS="-Wall -W -Wno-unused $CFLAGS"
|
|
AC_MSG_RESULT(yes)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
|
|
#
|
|
# Add any platform-specific compiler flags needed.
|
|
#
|
|
AC_MSG_CHECKING(for platform-specific compiler flags)
|
|
if test "x$GCC" = x
|
|
then
|
|
#
|
|
# Not GCC - assume it's the vendor's compiler.
|
|
#
|
|
case "$host_os" in
|
|
hpux*)
|
|
#
|
|
# HP's ANSI C compiler; flags suggested by Jost Martin.
|
|
# "-Ae" for ANSI C plus extensions such as "long long".
|
|
# "+O2", for optimization. XXX - works with "-g"?
|
|
#
|
|
CFLAGS="-Ae +O2 $CFLAGS"
|
|
AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
|
|
;;
|
|
darwin*)
|
|
#
|
|
# It may be called "cc", but it's really a GCC derivative
|
|
# with a problematic special precompiler and precompiled
|
|
# headers; turn off the special precompiler, as some
|
|
# apparently-legal code won't compile with its precompiled
|
|
# headers.
|
|
#
|
|
CFLAGS="-no-cpp-precomp $CFLAGS"
|
|
AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
|
|
;;
|
|
*)
|
|
AC_MSG_RESULT(none needed)
|
|
;;
|
|
esac
|
|
else
|
|
case "$host_os" in
|
|
solaris*)
|
|
# the X11 headers don't automatically include prototype info
|
|
# and a lot don't include the return type
|
|
CFLAGS="$CFLAGS -Wno-return-type -DFUNCPROTO=15"
|
|
AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
|
|
;;
|
|
darwin*)
|
|
#
|
|
# See comments above about Apple's lovely C compiler.
|
|
#
|
|
CFLAGS="-no-cpp-precomp $CFLAGS"
|
|
AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
|
|
;;
|
|
*)
|
|
AC_MSG_RESULT(none needed)
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
CFLAGS="$CFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
|
|
CPPFLAGS="$CPPFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
|
|
|
|
dnl Look in /usr/local for header files and libraries ?
|
|
AC_ARG_ENABLE(usr-local,
|
|
[ --enable-usr-local look for headers and libs in /usr/local tree. [default=yes]],enable_usr_local=$enableval,enable_usr_local=yes)
|
|
|
|
AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
|
|
if test "x$enable_usr_local" = "xyes" ; then
|
|
AC_MSG_RESULT(yes)
|
|
#
|
|
# Arrange that we search for header files in the source directory
|
|
# and in its "wiretap" subdirectory, as well as in "/usr/local/include",
|
|
# as various packages we use ("libpcap", "zlib", an SNMP library)
|
|
# may have been installed under "/usr/local/include".
|
|
#
|
|
CFLAGS="$CFLAGS -I/usr/local/include"
|
|
CPPFLAGS="$CPPFLAGS -I/usr/local/include"
|
|
|
|
#
|
|
# Arrange that we search for libraries in "/usr/local/lib".
|
|
#
|
|
AC_ETHEREAL_ADD_DASH_L(LDFLAGS, /usr/local/lib)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
fi
|
|
|
|
# Create DATAFILE_DIR #define for config.h
|
|
DATAFILE_DIR=$sysconfdir
|
|
DATAFILE_DIR=`(
|
|
test "x$prefix" = xNONE && prefix=$ac_default_prefix
|
|
test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
|
|
eval echo "$DATAFILE_DIR"
|
|
)`
|
|
AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$DATAFILE_DIR")
|
|
AC_SUBST(DATAFILE_DIR)
|
|
|
|
#
|
|
# If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
|
|
# link directory.
|
|
#
|
|
case "$host_os" in
|
|
solaris*)
|
|
AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
|
|
if test x$LD_LIBRARY_PATH != x ; then
|
|
LIBS="$LIBS -R$LD_LIBRARY_PATH"
|
|
AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
|
|
else
|
|
AC_MSG_RESULT(no -- this may be a problem in a few seconds)
|
|
fi
|
|
;;
|
|
esac
|
|
|
|
#
|
|
# Check for versions of "sed" inadequate to handle, in libtool, a list
|
|
# of object files as large as the list in Ethereal.
|
|
#
|
|
# On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
|
|
# as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
|
|
# symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
|
|
# their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
|
|
# is the only "sed" that comes with Solaris that can handle Ethereal.
|
|
#
|
|
# Add any checks here that are necessary for other OSes.
|
|
#
|
|
AC_ETHEREAL_GNU_SED_CHECK
|
|
if test "$HAVE_GNU_SED" = no ; then
|
|
case "$host_os" in
|
|
solaris*)
|
|
AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
|
|
case `which sed` in
|
|
/bin/sed|/usr/bin/sed|/usr/ucb/sed)
|
|
AC_MSG_RESULT(yes)
|
|
AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
|
|
;;
|
|
|
|
*)
|
|
AC_MSG_RESULT(no)
|
|
;;
|
|
esac
|
|
;;
|
|
|
|
*)
|
|
:
|
|
;;
|
|
esac
|
|
fi
|
|
|
|
# Enable/disable tethereal
|
|
|
|
GTK_OK=yes
|
|
|
|
AC_ARG_ENABLE(ethereal,
|
|
[ --enable-ethereal build GTK+-based ethereal. [default=yes]],,enable_ethereal=yes)
|
|
|
|
# GTK checks
|
|
# We don't add $GLIB_LIBS to LIBS, because we don't want to force all
|
|
# programs to be built with GTK+.
|
|
#
|
|
if test "x$enable_ethereal" = "xyes" ; then
|
|
AM_PATH_GTK(1.2.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no )
|
|
fi
|
|
|
|
# GLib checks
|
|
# This doesn't add GLIB_CFLAGS to CFLAGS, because AM_PATH_GTK will add
|
|
# GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a superset of CFLAGS.
|
|
# However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
|
|
# set when generating the Makefile, so we can make programs that require
|
|
# only GLib link with @GLIB_LIBS@ and make programs that require GTK+
|
|
# link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
|
|
# We don't add $GLIB_LIBS to LIBS, because we don't want to force all
|
|
# programs to be built with GLib.
|
|
#
|
|
if test "$GTK_OK" = "yes" -a "x$enable_ethereal" = "xyes" ; then
|
|
ethereal_bin="ethereal"
|
|
ethereal_man="ethereal.1"
|
|
ethereal_SUBDIRS="gtk"
|
|
|
|
# Ignore GLIB_CFLAGS
|
|
AM_PATH_GLIB(1.2.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
|
|
else
|
|
enable_ethereal="no"
|
|
ethereal_bin=""
|
|
ethereal_man=""
|
|
# Honor GLIB_CFLAGS
|
|
AM_PATH_GLIB(1.2.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
|
|
fi
|
|
|
|
#
|
|
# Check whether GLib modules are supported, to determine whether we
|
|
# can support plugins.
|
|
#
|
|
AC_MSG_CHECKING(whether GLib supports loadable modules)
|
|
ac_save_CFLAGS="$CFLAGS"
|
|
ac_save_LIBS="$LIBS"
|
|
CFLAGS="$CFLAGS $GLIB_CFLAGS"
|
|
LIBS="$GLIB_LIBS $LIBS"
|
|
AC_TRY_RUN([
|
|
#include <glib.h>
|
|
#include <gmodule.h>
|
|
#include <stdio.h>
|
|
#include <stdlib.h>
|
|
|
|
int
|
|
main ()
|
|
{
|
|
if (g_module_supported())
|
|
return 0; /* success */
|
|
else
|
|
return 1; /* failure */
|
|
}
|
|
], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
|
|
[echo $ac_n "cross compiling; assumed OK... $ac_c"])
|
|
CFLAGS="$ac_save_CFLAGS"
|
|
LIBS="$ac_save_LIBS"
|
|
if test "$ac_cv_glib_supports_modules" = yes ; then
|
|
AC_MSG_RESULT(yes)
|
|
have_plugins=yes
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
have_plugins=no
|
|
fi
|
|
|
|
|
|
AC_SUBST(ethereal_bin)
|
|
AC_SUBST(ethereal_man)
|
|
|
|
|
|
|
|
# Enable/disable tethereal
|
|
|
|
AC_ARG_ENABLE(tethereal,
|
|
[ --enable-tethereal build tethereal. [default=yes]],,enable_tethereal=yes)
|
|
|
|
if test "x$enable_tethereal" = "xyes" ; then
|
|
tethereal_bin="tethereal"
|
|
tethereal_man="tethereal.1"
|
|
else
|
|
tethereal_bin=""
|
|
tethereal_man=""
|
|
fi
|
|
AC_SUBST(tethereal_bin)
|
|
AC_SUBST(tethereal_man)
|
|
|
|
|
|
|
|
# Enable/disable editcap
|
|
|
|
AC_ARG_ENABLE(editcap,
|
|
[ --enable-editcap build editcap. [default=yes]],,enable_editcap=yes)
|
|
|
|
if test "x$enable_editcap" = "xyes" ; then
|
|
editcap_bin="editcap"
|
|
editcap_man="editcap.1"
|
|
else
|
|
editcap_bin=""
|
|
editcap_man=""
|
|
fi
|
|
AC_SUBST(editcap_bin)
|
|
AC_SUBST(editcap_man)
|
|
|
|
|
|
# Enable/disable mergecap
|
|
|
|
AC_ARG_ENABLE(mergecap,
|
|
[ --enable-mergecap build mergecap. [default=yes]],,enable_mergecap=yes)
|
|
|
|
if test "x$enable_mergecap" = "xyes" ; then
|
|
mergecap_bin="mergecap"
|
|
mergecap_man="mergecap.1"
|
|
else
|
|
mergecap_bin=""
|
|
mergecap_man=""
|
|
fi
|
|
AC_SUBST(mergecap_bin)
|
|
AC_SUBST(mergecap_man)
|
|
|
|
|
|
# Enable/disable text2pcap
|
|
|
|
AC_ARG_ENABLE(text2pcap,
|
|
[ --enable-text2pcap build text2pcap. [default=yes]],,enable_text2pcap=yes)
|
|
|
|
if test "x$enable_text2pcap" = "xyes" ; then
|
|
text2pcap_bin="text2pcap"
|
|
text2pcap_man="text2pcap.1"
|
|
else
|
|
text2pcap_bin=""
|
|
text2pcap_man=""
|
|
fi
|
|
AC_SUBST(text2pcap_bin)
|
|
AC_SUBST(text2pcap_man)
|
|
|
|
# Enable/disable idl2eth
|
|
|
|
AC_ARG_ENABLE(idl2eth,
|
|
[ --enable-idl2eth build idl2eth. [default=yes]],,enable_idl2eth=yes)
|
|
|
|
if test "x$enable_idl2eth" = "xyes" ; then
|
|
idl2eth_bin="idl2eth"
|
|
idl2eth_man="idl2eth.1"
|
|
else
|
|
idl2eth_bin=""
|
|
idl2eth_man=""
|
|
fi
|
|
AC_SUBST(idl2eth_bin)
|
|
AC_SUBST(idl2eth_man)
|
|
|
|
|
|
# Enable/disable dftest
|
|
|
|
AC_ARG_ENABLE(dftest,
|
|
[ --enable-dftest build dftest. [default=no]],,enable_dftest=no)
|
|
|
|
if test "x$enable_dftest" = "xyes" ; then
|
|
dftest_bin="dftest"
|
|
else
|
|
dftest_bin=""
|
|
fi
|
|
AC_SUBST(dftest_bin)
|
|
|
|
|
|
# Enable/disable randpkt
|
|
|
|
AC_ARG_ENABLE(randpkt,
|
|
[ --enable-randpkt build randpkt. [default=no]],,enable_randpkt=no)
|
|
|
|
if test "x$enable_randpkt" = "xyes" ; then
|
|
randpkt_bin="randpkt"
|
|
else
|
|
randpkt_bin=""
|
|
fi
|
|
AC_SUBST(randpkt_bin)
|
|
|
|
|
|
dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
|
|
dnl "gethostbyname()".
|
|
AC_ETHEREAL_GETHOSTBY_LIB_CHECK
|
|
|
|
dnl Checks for "connect()", used as a proxy for "socket()" - and
|
|
dnl "-lsocket", if we need it to get "connect()".
|
|
AC_ETHEREAL_SOCKET_LIB_CHECK
|
|
|
|
dnl pcap check
|
|
AC_MSG_CHECKING(whether to use libpcap for packet capture)
|
|
|
|
AC_ARG_WITH(pcap,
|
|
[ --with-pcap[=DIR] use libpcap for packet capturing. [default=yes]],
|
|
[
|
|
if test $withval = no
|
|
then
|
|
want_pcap=no
|
|
elif test $withval = yes
|
|
then
|
|
want_pcap=yes
|
|
else
|
|
want_pcap=yes
|
|
pcap_dir=$withval
|
|
fi
|
|
],[
|
|
want_pcap=yes
|
|
pcap_dir=
|
|
])
|
|
if test "x$want_pcap" = "xno" ; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
AC_ETHEREAL_PCAP_CHECK
|
|
AC_ETHEREAL_PCAP_VERSION_CHECK
|
|
fi
|
|
|
|
dnl zlib check
|
|
AC_ARG_ENABLE(zlib,
|
|
[ --enable-zlib use zlib to read compressed data. [default=yes]],,enable_zlib=yes)
|
|
|
|
AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
|
|
if test "x$enable_zlib" = "xno" ; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
AC_ETHEREAL_ZLIB_CHECK
|
|
if test "x$enable_zlib" = "xno" ; then
|
|
AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
|
|
fi
|
|
fi
|
|
|
|
|
|
dnl ipv6 check
|
|
AC_ARG_ENABLE(ipv6,
|
|
[ --enable-ipv6 use ipv6 name resolution, if available. [default=yes]],,enable_ipv6=yes)
|
|
|
|
AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
|
|
if test "x$enable_ipv6" = "xno" ; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
AC_ETHEREAL_IPV6_STACK
|
|
fi
|
|
|
|
|
|
dnl Check if ethereal should be installed setuid
|
|
AC_ARG_ENABLE(setuid-install,
|
|
[ --enable-setuid-install install ethereal as setuid. DANGEROUS!!! [default=no]],,enable_setuid_install=no)
|
|
|
|
AC_MSG_CHECKING(whether to install ethereal setuid)
|
|
if test "x$enable_setuid_install" = "xno" ; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
fi
|
|
|
|
AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
|
|
|
|
dnl Checks for header files.
|
|
AC_HEADER_STDC
|
|
AC_CHECK_HEADERS(fcntl.h sys/ioctl.h sys/time.h unistd.h stdarg.h netdb.h)
|
|
AC_CHECK_HEADERS(sys/stat.h sys/sockio.h sys/types.h sys/socket.h)
|
|
AC_CHECK_HEADERS(sys/wait.h)
|
|
AC_CHECK_HEADERS(netinet/in.h)
|
|
AC_CHECK_HEADERS(stddef.h)
|
|
AC_CHECK_HEADERS(arpa/inet.h)
|
|
AC_CHECK_HEADERS(iconv.h)
|
|
|
|
dnl SSL Check
|
|
SSL_LIBS=''
|
|
AC_MSG_CHECKING(whether to use SSL library if available)
|
|
if test "x$enable_ssl" = "xno" ; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
AC_ETHEREAL_SSL_CHECK
|
|
fi
|
|
AC_SUBST(SSL_LIBS)
|
|
|
|
dnl SNMP Check
|
|
AC_ARG_ENABLE(snmp,
|
|
[ --enable-snmp use SNMP library, if available. [default=yes]],,enable_snmp=yes)
|
|
|
|
SNMP_LIBS=''
|
|
AC_MSG_CHECKING(whether to use SNMP library if available)
|
|
if test "x$enable_snmp" = "xno" ; then
|
|
AC_MSG_RESULT(no)
|
|
else
|
|
AC_MSG_RESULT(yes)
|
|
AC_ETHEREAL_UCDSNMP_CHECK
|
|
AC_CHECK_HEADERS(ucd-snmp/snmp.h ucd-snmp/version.h snmp/snmp.h snmp/version.h)
|
|
|
|
#
|
|
# If we found both UCD and CMU SNMP headers, die, as both
|
|
# packages install the SNMP library as "libsnmp", so either
|
|
# only one of them is present or they're in different
|
|
# directories, and we run the risk of picking up the headers
|
|
# from one and the library from another.
|
|
#
|
|
if test "$ac_cv_header_ucd_snmp_snmp_h" = yes -a \
|
|
"$ac_cv_header_snmp_snmp_h" = yes ; then
|
|
AC_MSG_ERROR([Both UCD and CMU SNMP libraries found - uninstall one of them.])
|
|
fi
|
|
|
|
#
|
|
# Look for the string 'sbuf' in ucd-snmp/mib.h. If found, assume
|
|
# we've encountered a Red Hat-modified version of UCD SNMP.
|
|
#
|
|
# XXX - Check for 'binit()' in parse.h
|
|
#
|
|
AC_EGREP_HEADER(sprint_objid.*sbuf, ucd-snmp/mib.h,
|
|
AC_DEFINE(RED_HAT_MODIFIED_UCD_SNMP))
|
|
|
|
|
|
#
|
|
# This may require "-lkstat" on Solaris, sigh.
|
|
#
|
|
AC_CHECK_LIB(snmp, sprint_objid,
|
|
SNMP_LIBS=-lsnmp,
|
|
[
|
|
#
|
|
# Throw away the cached "we didn't find it" answer.
|
|
#
|
|
unset ac_cv_lib_snmp_sprint_objid
|
|
AC_CHECK_LIB(snmp, sprint_objid,
|
|
[
|
|
#
|
|
# Throw away the cached "we found it" answer, so that if
|
|
# we rerun "configure", we don't just blow off this check
|
|
# and blithely assume that we don't need "-lkstat".
|
|
#
|
|
# XXX - autoconf really needs a way to test for a given
|
|
# routine in a given library *and* to test whether additional
|
|
# "-L"/"-R"/whatever flags are needed *before* the "-l"
|
|
# flag for the library and to test whether additional libraries
|
|
# are needed after the library *and* to cache all that
|
|
# information.
|
|
#
|
|
unset ac_cv_lib_snmp_sprint_objid
|
|
SNMP_LIBS="-lsnmp -lkstat"
|
|
],,$SOCKET_LIBS $NSL_LIBS $SSL_LIBS -lkstat
|
|
)
|
|
], $SOCKET_LIBS $NSL_LIBS $SSL_LIBS
|
|
)
|
|
|
|
#
|
|
# If we have SNMP header files but didn't find "sprint_objid()",
|
|
# fail, as there's something wrong (perhaps the user needs to
|
|
# specify "--with-ssl").
|
|
#
|
|
if test '(' "$ac_cv_header_ucd_snmp_snmp_h" = yes -o \
|
|
"$ac_cv_header_snmp_snmp_h" = yes ')' -a \
|
|
"$ac_cv_lib_snmp_sprint_objid" = no; then
|
|
AC_MSG_ERROR([SNMP header files found, but sprint_objid not found in SNMP library.])
|
|
fi
|
|
fi
|
|
AC_SUBST(SNMP_LIBS)
|
|
|
|
dnl Checks for typedefs, structures, and compiler characteristics.
|
|
# AC_C_CONST
|
|
|
|
# We need to know whether "struct sockaddr" has an "sa_len" member
|
|
# for get_interface_list().
|
|
|
|
AC_ETHEREAL_STRUCT_SA_LEN
|
|
|
|
# We must know our byte order
|
|
AC_C_BIGENDIAN
|
|
|
|
# Checks whether "-traditional" is needed when using "ioctl".
|
|
# XXX - do we need this?
|
|
AC_PROG_GCC_TRADITIONAL
|
|
|
|
# If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
|
|
# then this won't work.
|
|
SNPRINTF_C=""
|
|
SNPRINTF_O=""
|
|
AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
|
|
SNPRINTF_O="snprintf.o" [AC_DEFINE(NEED_SNPRINTF_H)])
|
|
if test "$ac_cv_func_snprintf" = no ; then
|
|
SNPRINTF_C="snprintf.c"
|
|
SNPRINTF_O="snprintf.o"
|
|
fi
|
|
AC_SUBST(SNPRINTF_C)
|
|
AC_SUBST(SNPRINTF_O)
|
|
|
|
AC_CHECK_FUNC(strerror, STRERROR_O="",
|
|
STRERROR_O="strerror.o" [AC_DEFINE(NEED_STRERROR_H)])
|
|
if test "$ac_cv_func_strerror" = no ; then
|
|
STRERROR_C="strerror.c"
|
|
STRERROR_O="strerror.o"
|
|
fi
|
|
AC_SUBST(STRERROR_C)
|
|
AC_SUBST(STRERROR_O)
|
|
|
|
AC_CHECK_FUNC(strcasecmp, STRCASECMP_O="",
|
|
STRCASECMP_O="strcasecmp.o")
|
|
if test "$ac_cv_func_strcasecmp" = no ; then
|
|
STRCASECMP_C="strcasecmp.c"
|
|
STRCASECMP_O="strcasecmp.o"
|
|
fi
|
|
AC_SUBST(STRCASECMP_C)
|
|
AC_SUBST(STRCASECMP_O)
|
|
|
|
AC_CHECK_FUNC(strncasecmp, STRNCASECMP_O="",
|
|
STRNCASECMP_O="strncasecmp.o")
|
|
if test "$ac_cv_func_strncasecmp" = no ; then
|
|
STRNCASECMP_C="strncasecmp.c"
|
|
STRNCASECMP_O="strncasecmp.o"
|
|
fi
|
|
AC_SUBST(STRNCASECMP_C)
|
|
AC_SUBST(STRNCASECMP_O)
|
|
|
|
AC_CHECK_FUNC(mkstemp, MKSTEMP_O="",
|
|
MKSTEMP_O="mkstemp.o")
|
|
if test "$ac_cv_func_mkstemp" = no ; then
|
|
MKSTEMP_C="mkstemp.c"
|
|
MKSTEMP_O="mkstemp.o"
|
|
fi
|
|
AC_SUBST(MKSTEMP_C)
|
|
AC_SUBST(MKSTEMP_O)
|
|
|
|
AC_CHECK_FUNC(strptime, STRPTIME_O="",
|
|
STRPTIME_O="strptime.o" [AC_DEFINE(NEED_STRPTIME_H)])
|
|
if test "$ac_cv_func_strptime" = no ; then
|
|
STRPTIME_C="strptime.c"
|
|
STRPTIME_O="strptime.o"
|
|
fi
|
|
AC_SUBST(STRPTIME_C)
|
|
AC_SUBST(STRPTIME_O)
|
|
|
|
AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
|
|
|
|
dnl blank for now, but will be used in future
|
|
AC_SUBST(ethereal_SUBDIRS)
|
|
|
|
dnl
|
|
dnl check whether plugins should be enabled and, if they should be,
|
|
dnl check for plugins directory - stolen from Amanda's configure.in
|
|
dnl
|
|
PLUGIN_DIR="$libdir/ethereal/plugins/$VERSION"
|
|
AC_ARG_WITH(plugins,
|
|
[ --with-plugins[=DIR] support plugins (installed in DIR, if supplied).],
|
|
[
|
|
case "$withval" in
|
|
"" | y | ye | yes )
|
|
if test x$have_plugins = xno
|
|
then
|
|
AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
|
|
fi
|
|
;;
|
|
n | no)
|
|
have_plugins=no
|
|
;;
|
|
*)
|
|
if test x$have_plugins = xno
|
|
then
|
|
AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
|
|
fi
|
|
PLUGIN_DIR="$withval"
|
|
;;
|
|
esac
|
|
]
|
|
)
|
|
|
|
AM_CONDITIONAL(HAVE_PLUGINS, test x$have_plugins = xyes)
|
|
if test x$have_plugins = xyes
|
|
then
|
|
AC_DEFINE(HAVE_PLUGINS)
|
|
PLUGIN_DIR=`(
|
|
test "x$prefix" = xNONE && prefix=$ac_default_prefix
|
|
test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
|
|
eval echo "$PLUGIN_DIR"
|
|
)`
|
|
AC_DEFINE_UNQUOTED(PLUGIN_DIR,"$PLUGIN_DIR", [Plugin installation directory])
|
|
else
|
|
AC_DEFINE(PLUGIN_DIR,NULL)
|
|
fi
|
|
AC_SUBST(PLUGIN_DIR)
|
|
|
|
dnl libtool defs
|
|
AC_LIBTOOL_DLOPEN
|
|
AM_PROG_LIBTOOL
|
|
AC_SUBST(LIBTOOL_DEPS)
|
|
|
|
AM_CONFIG_HEADER(config.h)
|
|
AC_CONFIG_SUBDIRS(epan wiretap)
|
|
AC_OUTPUT(
|
|
Makefile
|
|
doc/Makefile
|
|
gtk/Makefile
|
|
packaging/Makefile
|
|
packaging/nsis/Makefile
|
|
packaging/rpm/Makefile
|
|
packaging/rpm/SPECS/Makefile
|
|
packaging/rpm/SPECS/ethereal.spec
|
|
packaging/svr4/Makefile
|
|
packaging/svr4/checkinstall
|
|
packaging/svr4/pkginfo
|
|
plugins/Makefile
|
|
plugins/gryphon/Makefile
|
|
plugins/mgcp/Makefile
|
|
plugins/giop/Makefile
|
|
tools/Makefile
|
|
tools/lemon/Makefile
|
|
,)
|
|
|
|
|
|
# Pretty messages
|
|
|
|
if test "x$enable_setuid_install" = "xyes" ; then
|
|
setuid_message="yes (DANGEROUS!!!)"
|
|
else
|
|
setuid_message="no"
|
|
fi
|
|
|
|
if test "x$SNMP_LIBS" = "x" ; then
|
|
snmp_libs_message="no"
|
|
else
|
|
snmp_libs_message="yes"
|
|
fi
|
|
|
|
|
|
|
|
echo ""
|
|
echo "The Ethereal package has been configured with the following options."
|
|
echo " Build ethereal : $enable_ethereal"
|
|
echo " Build tethereal : $enable_tethereal"
|
|
echo " Build editcap : $enable_editcap"
|
|
echo " Build mergecap : $enable_mergecap"
|
|
echo " Build text2pcap : $enable_text2pcap"
|
|
echo " Build idl2eth : $enable_idl2eth"
|
|
echo " Build randpkt : $enable_randpkt"
|
|
echo " Build dftest : $enable_dftest"
|
|
echo ""
|
|
echo " Install setuid : $setuid_message"
|
|
echo " Use plugins : $have_plugins"
|
|
echo " Use pcap library : $want_pcap"
|
|
echo " Use zlib library : $enable_zlib"
|
|
echo " Use IPv6 name resolution : $enable_ipv6"
|
|
echo " Use SNMP library : $snmp_libs_message"
|