mirror of https://gerrit.osmocom.org/osmo-pcap
198 lines
6.7 KiB
Plaintext
198 lines
6.7 KiB
Plaintext
dnl Process this file with autoconf to produce a configure script
|
|
AC_INIT([osmo-pcap],
|
|
m4_esyscmd([./git-version-gen .tarball-version]),
|
|
[openbsc-devel@lists.openbsc.org])
|
|
|
|
AM_INIT_AUTOMAKE([dist-bzip2])
|
|
AC_CONFIG_TESTDIR(tests)
|
|
AC_ARG_ENABLE(manuals,
|
|
[AS_HELP_STRING(
|
|
[--enable-manuals],
|
|
[Generate manual PDFs [default=no]],
|
|
)],
|
|
[osmo_ac_build_manuals=$enableval], [osmo_ac_build_manuals="no"])
|
|
AM_CONDITIONAL([BUILD_MANUALS], [test x"$osmo_ac_build_manuals" = x"yes"])
|
|
AC_ARG_VAR(OSMO_GSM_MANUALS_DIR, [path to common osmo-gsm-manuals files, overriding pkg-config and "../osmo-gsm-manuals"
|
|
fallback])
|
|
if test x"$osmo_ac_build_manuals" = x"yes"
|
|
then
|
|
# Find OSMO_GSM_MANUALS_DIR (env, pkg-conf, fallback)
|
|
if test -n "$OSMO_GSM_MANUALS_DIR"; then
|
|
echo "checking for OSMO_GSM_MANUALS_DIR... $OSMO_GSM_MANUALS_DIR (from env)"
|
|
else
|
|
OSMO_GSM_MANUALS_DIR="$($PKG_CONFIG osmo-gsm-manuals --variable=osmogsmmanualsdir 2>/dev/null)"
|
|
if test -n "$OSMO_GSM_MANUALS_DIR"; then
|
|
echo "checking for OSMO_GSM_MANUALS_DIR... $OSMO_GSM_MANUALS_DIR (from pkg-conf)"
|
|
else
|
|
OSMO_GSM_MANUALS_DIR="../osmo-gsm-manuals"
|
|
echo "checking for OSMO_GSM_MANUALS_DIR... $OSMO_GSM_MANUALS_DIR (fallback)"
|
|
fi
|
|
fi
|
|
if ! test -d "$OSMO_GSM_MANUALS_DIR"; then
|
|
AC_MSG_ERROR("OSMO_GSM_MANUALS_DIR does not exist! Install osmo-gsm-manuals or set OSMO_GSM_MANUALS_DIR.")
|
|
fi
|
|
|
|
# Find and run check-depends
|
|
CHECK_DEPENDS="$OSMO_GSM_MANUALS_DIR/check-depends.sh"
|
|
if ! test -x "$CHECK_DEPENDS"; then
|
|
CHECK_DEPENDS="osmo-gsm-manuals-check-depends"
|
|
fi
|
|
if ! $CHECK_DEPENDS; then
|
|
AC_MSG_ERROR("missing dependencies for --enable-manuals")
|
|
fi
|
|
|
|
# Put in Makefile with absolute path
|
|
OSMO_GSM_MANUALS_DIR="$(realpath "$OSMO_GSM_MANUALS_DIR")"
|
|
AC_SUBST([OSMO_GSM_MANUALS_DIR])
|
|
fi
|
|
|
|
CFLAGS="$CFLAGS -std=gnu11"
|
|
|
|
dnl kernel style compile messages
|
|
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
|
|
|
|
dnl include release helper
|
|
RELMAKE='-include osmo-release.mk'
|
|
AC_SUBST([RELMAKE])
|
|
|
|
dnl checks for programs
|
|
AC_PROG_MAKE_SET
|
|
AC_PROG_CC
|
|
AC_PROG_INSTALL
|
|
AC_PROG_RANLIB
|
|
|
|
dnl check for pkg-config (explained in detail in libosmocore/configure.ac)
|
|
AC_PATH_PROG(PKG_CONFIG_INSTALLED, pkg-config, no)
|
|
if test "x$PKG_CONFIG_INSTALLED" = "xno"; then
|
|
AC_MSG_WARN([You need to install pkg-config])
|
|
fi
|
|
PKG_PROG_PKG_CONFIG([0.20])
|
|
|
|
dnl checks for header files
|
|
AC_HEADER_STDC
|
|
|
|
AC_ARG_ENABLE(sanitize,
|
|
[AS_HELP_STRING(
|
|
[--enable-sanitize],
|
|
[Compile with address sanitizer enabled],
|
|
)],
|
|
[sanitize=$enableval], [sanitize="no"])
|
|
if test x"$sanitize" = x"yes"
|
|
then
|
|
CFLAGS="$CFLAGS -fsanitize=address -fsanitize=undefined"
|
|
CPPFLAGS="$CPPFLAGS -fsanitize=address -fsanitize=undefined"
|
|
fi
|
|
|
|
AC_ARG_ENABLE(werror,
|
|
[AS_HELP_STRING(
|
|
[--enable-werror],
|
|
[Turn all compiler warnings into errors, with exceptions:
|
|
a) deprecation (allow upstream to mark deprecation without breaking builds);
|
|
b) "#warning" pragmas (allow to remind ourselves of errors without breaking builds)
|
|
]
|
|
)],
|
|
[werror=$enableval], [werror="no"])
|
|
if test x"$werror" = x"yes"
|
|
then
|
|
WERROR_FLAGS="-Werror"
|
|
WERROR_FLAGS+=" -Wno-error=deprecated -Wno-error=deprecated-declarations"
|
|
WERROR_FLAGS+=" -Wno-error=cpp" # "#warning"
|
|
CFLAGS="$CFLAGS $WERROR_FLAGS"
|
|
CPPFLAGS="$CPPFLAGS $WERROR_FLAGS"
|
|
fi
|
|
|
|
# https://www.freedesktop.org/software/systemd/man/daemon.html
|
|
AC_ARG_WITH([systemdsystemunitdir],
|
|
[AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files])],,
|
|
[with_systemdsystemunitdir=auto])
|
|
AS_IF([test "x$with_systemdsystemunitdir" = "xyes" -o "x$with_systemdsystemunitdir" = "xauto"], [
|
|
def_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
|
|
AS_IF([test "x$def_systemdsystemunitdir" = "x"],
|
|
[AS_IF([test "x$with_systemdsystemunitdir" = "xyes"],
|
|
[AC_MSG_ERROR([systemd support requested but pkg-config unable to query systemd package])])
|
|
with_systemdsystemunitdir=no],
|
|
[with_systemdsystemunitdir="$def_systemdsystemunitdir"])])
|
|
AS_IF([test "x$with_systemdsystemunitdir" != "xno"],
|
|
[AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])])
|
|
AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$with_systemdsystemunitdir" != "xno"])
|
|
|
|
AC_ARG_ENABLE([external_tests],
|
|
AC_HELP_STRING([--enable-external-tests],
|
|
[Include the VTY tests in make check [default=no]]),
|
|
[enable_ext_tests="$enableval"],[enable_ext_tests="no"])
|
|
if test "x$enable_ext_tests" = "xyes" ; then
|
|
AM_PATH_PYTHON
|
|
AC_CHECK_PROG(OSMOTESTEXT_CHECK,osmotestvty.py,yes)
|
|
if test "x$OSMOTESTEXT_CHECK" != "xyes" ; then
|
|
AC_MSG_ERROR([Please install osmocom-python to run the VTY tests.])
|
|
fi
|
|
fi
|
|
AC_MSG_CHECKING([whether to enable VTY tests])
|
|
AC_MSG_RESULT([$enable_ext_tests])
|
|
AM_CONDITIONAL(ENABLE_EXT_TESTS, test "x$enable_ext_tests" = "xyes")
|
|
|
|
dnl Checks for typedefs, structures and compiler characteristics
|
|
AC_ARG_WITH([pcap-config],
|
|
AC_HELP_STRING([--with-pcap-config=FILE], [Use given pcap-config]),
|
|
[pcapcfg="$withval" ],
|
|
[AC_PATH_PROG([pcapcfg], [pcap-config], [])])
|
|
if test x$pcapcfg = "x"; then
|
|
AC_MSG_ERROR([pcap-config can not be found])
|
|
fi
|
|
|
|
dnl CentOS 5 and Debian 6.0 do not ship with a pcap-config and we somehow
|
|
dnl need to support these versions. Once we drop support for these two distros
|
|
dnl the below can be simplified again.
|
|
AC_ARG_VAR([PCAP_LIBS], [PCAP library files])
|
|
AC_ARG_VAR([PCAP_CFLAGS], [PCAP C compiler flags])
|
|
|
|
if test "x$ac_cv_env_PCAP_LIBS_set" != "xset"; then
|
|
PCAP_LIBS=`$pcapcfg --libs`
|
|
fi
|
|
|
|
if test "x$ac_cv_env_PCAP_CFLAGS_set" != "xset"; then
|
|
PCAP_CFLAGS=`$pcapcfg --cflags`
|
|
fi
|
|
AC_SUBST([PCAP_LIBS])
|
|
AC_SUBST([PCAP_CFLAGS])
|
|
|
|
dnl checks for libraries
|
|
PKG_CHECK_MODULES(LIBOSMOCORE, libosmocore >= 1.9.0)
|
|
# libosmogb: needed for osmocom/gprs includes
|
|
PKG_CHECK_MODULES(LIBOSMOGB, libosmogb >= 1.9.0)
|
|
PKG_CHECK_MODULES(LIBOSMOGSM, libosmogsm >= 1.9.0)
|
|
PKG_CHECK_MODULES(LIBOSMOVTY, libosmovty >= 1.9.0)
|
|
PKG_CHECK_MODULES(LIBZMQ, libzmq >= 3.2.2)
|
|
PKG_CHECK_MODULES(LIBGNUTLS, gnutls)
|
|
|
|
|
|
# Coverage build taken from WebKit's configure.in
|
|
AC_MSG_CHECKING([whether to enable code coverage support])
|
|
AC_ARG_ENABLE(coverage,
|
|
AC_HELP_STRING([--enable-coverage],
|
|
[enable code coverage support [default=no]]),
|
|
[],[enable_coverage="no"])
|
|
AC_MSG_RESULT([$enable_coverage])
|
|
if test "$enable_coverage" = "yes"; then
|
|
COVERAGE_CFLAGS="-ftest-coverage -fprofile-arcs"
|
|
COVERAGE_LDFLAGS="-ftest-coverage -fprofile-arcs"
|
|
AC_SUBST([COVERAGE_CFLAGS])
|
|
AC_SUBST([COVERAGE_LDFLAGS])
|
|
fi
|
|
|
|
AM_CONFIG_HEADER(osmopcapconfig.h)
|
|
|
|
dnl Generate the output
|
|
AC_OUTPUT(
|
|
include/Makefile
|
|
include/osmo-pcap/Makefile
|
|
src/Makefile
|
|
contrib/Makefile
|
|
contrib/systemd/Makefile
|
|
contrib/osmo-pcap.spec
|
|
doc/Makefile
|
|
doc/examples/Makefile
|
|
doc/manuals/Makefile
|
|
tests/Makefile
|
|
Makefile)
|