"
 (C) 2011-2013 by Holger Hans Peter Freyther
 All Rights Reserved

 This program is free software: you can redistribute it and/or modify
 it under the terms of the GNU Affero General Public License as
 published by the Free Software Foundation, either version 3 of the
 License, or (at your option) any later version.

 This program is distributed in the hope that it will be useful,
 but WITHOUT ANY WARRANTY; without even the implied warranty of
 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 GNU Affero General Public License for more details.

 You should have received a copy of the GNU Affero General Public License
 along with this program.  If not, see <http://www.gnu.org/licenses/>.
"

Object subclass: OsmoAppConnection [
    | socket writeQueue demuxer muxer dispatcher ctrlBlock |
    <category: 'OsmoNetwork-Control'>
    <comment: 'I connect to a OpenBSC App on the Control Port and wait for
TRAPS coming from the server and will act on these.'>

    onCtrlData: aBlock [
        <category: 'ctrl-dispatch'>
        ctrlBlock := aBlock
    ]

    handleCTRL: aCtrl [
        <category: 'ctrl-dispatch'>
        ctrlBlock value: aCtrl.
    ]

    connect: aPort [
        | ipa |
        <category: 'connect'>

        socket ifNotNil: [socket close].

        socket := Sockets.Socket remote: '127.0.0.1' port: aPort.
        writeQueue := SharedQueue new.

        demuxer := IPADemuxer initOn: socket.
        muxer := IPAMuxer initOn: writeQueue.

        dispatcher := IPADispatcher new.
        dispatcher initialize.
        dispatcher
            addHandler: IPAConstants protocolOsmoCTRL
            on: self with: #handleCTRL:.

        ipa := IPAProtoHandler new.
        ipa registerOn: dispatcher.
        ipa muxer: muxer.
    ]

    connect [
	<category: 'connect'>
	^ self connect: 4250.
    ]

    sendCtrlData: aData [
        muxer nextPut: aData with: IPAConstants protocolOsmoCTRL.
    ]

    sendOne [
        | msg |
        <category: 'dispatch'>

        msg := writeQueue next.
        socket nextPutAllFlush: msg.
    ]

    dispatchOne [
        | msg |
        <category: 'dispatch'>

        msg := demuxer next.
        dispatcher dispatch: msg first with: msg second.
    ]
]