d456079b7e
some smaller changes by me. - README.cmake Document how to (one day) run on Windows - CMakeLists.txt Use MSVC compiler flags for MSVC instead of gcc flags - FindWSWinLibs.cmake New: Creates HINTS for finding includes and libraries inside the Wireshark support library installation. - FindXXX.cmake Make use of HINTS generated by FindWSWinLibs.cmake This has not really been tested on Windows as my installation seems to have automagically downloaded some fixes and is in an inconsistent state since. Will probably need to reinstall. svn path=/trunk/; revision=52194
45 lines
1.3 KiB
CMake
45 lines
1.3 KiB
CMake
#
|
|
# $Id$
|
|
#
|
|
# - Find GeoIP
|
|
# Find the native GEOIP includes and library
|
|
#
|
|
# GEOIP_INCLUDE_DIRS - where to find GeoIP.h, etc.
|
|
# GEOIP_LIBRARIES - List of libraries when using GeoIP.
|
|
# GEOIP_FOUND - True if GeoIP found.
|
|
|
|
|
|
IF (GEOIP_INCLUDE_DIRS)
|
|
# Already in cache, be silent
|
|
SET(GEOIP_FIND_QUIETLY TRUE)
|
|
ENDIF (GEOIP_INCLUDE_DIRS)
|
|
|
|
INCLUDE(FindWSWinLibs)
|
|
FindWSWinLibs("GeoIP-.*" "GEOIP_HINTS")
|
|
|
|
FIND_PATH(GEOIP_INCLUDE_DIR GeoIP.h HINTS "${GEOIP_HINTS}/include" )
|
|
|
|
SET(GEOIP_NAMES GeoIP libGeoIP-1)
|
|
FIND_LIBRARY(GEOIP_LIBRARY NAMES ${GEOIP_NAMES} HINTS "${GEOIP_HINTS}/lib" )
|
|
|
|
# handle the QUIETLY and REQUIRED arguments and set GEOIP_FOUND to TRUE if
|
|
# all listed variables are TRUE
|
|
INCLUDE(FindPackageHandleStandardArgs)
|
|
FIND_PACKAGE_HANDLE_STANDARD_ARGS(GEOIP DEFAULT_MSG GEOIP_LIBRARY GEOIP_INCLUDE_DIR)
|
|
|
|
IF(GEOIP_FOUND)
|
|
SET(GEOIP_LIBRARIES ${GEOIP_LIBRARY} )
|
|
SET(GEOIP_INCLUDE_DIRS ${GEOIP_INCLUDE_DIR} )
|
|
INCLUDE(CheckFunctionExists)
|
|
SET(CMAKE_REQUIRED_INCLUDES ${GEOIP_INCLUDE_DIRS})
|
|
SET(CMAKE_REQUIRED_LIBRARIES ${GEOIP_LIBRARIES})
|
|
CHECK_FUNCTION_EXISTS("GeoIP_country_name_by_ipnum_v6" HAVE_GEOIP_V6)
|
|
SET(CMAKE_REQUIRED_INCLUDES "")
|
|
SET(CMAKE_REQUIRED_LIBRARIES "")
|
|
ELSE(GEOIP_FOUND)
|
|
SET(GEOIP_LIBRARIES )
|
|
SET(GEOIP_INCLUDE_DIRS )
|
|
ENDIF(GEOIP_FOUND)
|
|
|
|
MARK_AS_ADVANCED( GEOIP_LIBRARIES GEOIP_INCLUDE_DIRS )
|