From 03531df897d43f04180583578fb6bc151924b4d0 Mon Sep 17 00:00:00 2001
From: Lev Walkin <vlm@lionet.info>
Date: Thu, 19 Oct 2017 00:23:12 -0700
Subject: [PATCH] stronger detection of fuzzing infrastructure (linkability)

---
 .gitignore                           |  1 +
 configure.ac                         | 21 +++++---
 m4/ax_check_compile_and_link_flag.m4 | 72 ++++++++++++++++++++++++++++
 3 files changed, 87 insertions(+), 7 deletions(-)
 create mode 100644 m4/ax_check_compile_and_link_flag.m4

diff --git a/.gitignore b/.gitignore
index 5492535a..c38ee774 100644
--- a/.gitignore
+++ b/.gitignore
@@ -19,6 +19,7 @@ Makefile
 Makefile.in
 ylwrap
 m4/*
+!m4/ax_*.m4
 
 # Generated by `./configure`
 config.h
diff --git a/configure.ac b/configure.ac
index 6f619306..33325357 100644
--- a/configure.ac
+++ b/configure.ac
@@ -211,7 +211,6 @@ Check out https://clang.llvm.org/docs/AddressSanitizer.html#how-to-build])])
           [SANITIZER_CFLAGS="${SANITIZER_CFLAGS} -fno-omit-frame-pointer"])
 ])
 
-
 dnl Enable LibFuzzer, if supported.
 LIBFUZZER_CFLAGS=""
 AC_ARG_ENABLE([test-fuzzer],
@@ -219,13 +218,21 @@ AC_ARG_ENABLE([test-fuzzer],
         [Enable LLVM LibFuzzer for randomized testing])],
     [enable_test_fuzzer=$enableval], [enable_test_fuzzer=no])
 AS_IF([test "x$enable_test_fuzzer" != xno], [
-    AX_CHECK_COMPILE_FLAG([-fsanitize=fuzzer],
-      [LIBFUZZER_CFLAGS="${FUZZER_CFLAGS} -fsanitize=fuzzer -DENABLE_LIBFUZZER"],
-      [
-            AC_MSG_FAILURE(
+    AX_CHECK_COMPILE_AND_LINK_FLAG([-fsanitize=fuzzer],
+    [LIBFUZZER_CFLAGS="-fsanitize=fuzzer -DENABLE_LIBFUZZER"],
+    [AC_MSG_FAILURE(
 [--enable-test-fuzzer=$enable_test_fuzzer is not supported on a target system.
-Check out http://llvm.org/docs/LibFuzzer.html])
-      ])
+Check out http://llvm.org/docs/LibFuzzer.html])],
+    [],
+    [AC_LANG_SOURCE([[
+    #include <sys/types.h>
+    int LLVMFuzzerTestOneInput(const unsigned char *Data, size_t Size);
+    int LLVMFuzzerTestOneInput(const unsigned char *Data, size_t Size) {
+        (void)Data;
+        (void)Size;
+        return 0;
+    }
+    ]])])
 ])
 
 TESTSUITE_CFLAGS="${TESTSUITE_CFLAGS} ${SANITIZER_CFLAGS}"
diff --git a/m4/ax_check_compile_and_link_flag.m4 b/m4/ax_check_compile_and_link_flag.m4
new file mode 100644
index 00000000..36d7eae9
--- /dev/null
+++ b/m4/ax_check_compile_and_link_flag.m4
@@ -0,0 +1,72 @@
+# SYNOPSIS
+#
+#   AX_CHECK_COMPILE_AND_LINK_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
+#
+# DESCRIPTION
+#
+#   Check whether the given FLAG works with the current language's compiler
+#   or gives an error.  (Warnings, however, are ignored)
+#
+#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
+#   success/failure.
+#
+#   If EXTRA-FLAGS is defined, it is added to the current language's default
+#   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
+#   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
+#   force the compiler to issue an error when a bad flag is given.
+#
+#   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
+#
+#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
+#   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
+#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
+#   Copyright (c) 2017 Lev Walkin <vlm@lionet.info>
+#
+#   This program is free software: you can redistribute it and/or modify it
+#   under the terms of the GNU General Public License as published by the
+#   Free Software Foundation, either version 3 of the License, or (at your
+#   option) any later version.
+#
+#   This program is distributed in the hope that it will be useful, but
+#   WITHOUT ANY WARRANTY; without even the implied warranty of
+#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+#   Public License for more details.
+#
+#   You should have received a copy of the GNU General Public License along
+#   with this program. If not, see <http://www.gnu.org/licenses/>.
+#
+#   As a special exception, the respective Autoconf Macro's copyright owner
+#   gives unlimited permission to copy, distribute and modify the configure
+#   scripts that are the output of Autoconf when processing the Macro. You
+#   need not follow the terms of the GNU General Public License when using
+#   or distributing such scripts, even though portions of the text of the
+#   Macro appear in them. The GNU General Public License (GPL) does govern
+#   all other use of the material that constitutes the Autoconf Macro.
+#
+#   This special exception to the GPL applies to versions of the Autoconf
+#   Macro released by the Autoconf Archive. When you make and distribute a
+#   modified version of the Autoconf Macro, you may extend this special
+#   exception to the GPL to apply to your modified version as well.
+
+#serial 1
+
+AC_DEFUN([AX_CHECK_COMPILE_AND_LINK_FLAG],
+[AC_PREREQ(2.61)dnl
+AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]clflags_$4_$1])dnl
+AC_CACHE_CHECK([whether _AC_LANG compiler and linker accept $1], CACHEVAR, [
+  ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
+  _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
+  AC_LINK_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
+    [AS_VAR_SET(CACHEVAR,[yes])],
+    [AS_VAR_SET(CACHEVAR,[no])])
+  _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
+AS_IF([test x"AS_VAR_GET(CACHEVAR)" = xyes],
+  [m4_default([$2], :)],
+  [m4_default([$3], :)])
+AS_VAR_POPDEF([CACHEVAR])dnl
+])dnl AX_CHECK_COMPILE_AND_LINK_FLAG
+