forked from osmocom/wireshark
MSYS2: Add PKGBUILD
This commit is contained in:
parent
d00bd20fea
commit
1229b0a999
|
@ -0,0 +1,88 @@
|
|||
# Maintainer: Wireshark Core Team <wireshark-dev@wireshark.org>
|
||||
|
||||
_realname=wireshark
|
||||
pkgbase=mingw-w64-${_realname}-git
|
||||
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}-git")
|
||||
pkgver=4.1.0rc0.1408.gd00bd20fea
|
||||
pkgrel=1
|
||||
pkgdesc="Network traffic and protocol analyzer/sniffer"
|
||||
arch=('any')
|
||||
mingw_arch=('mingw64' 'ucrt64' 'clang64')
|
||||
url="https://www.wireshark.org"
|
||||
license=('GPL2')
|
||||
depends=("${MINGW_PACKAGE_PREFIX}-brotli"
|
||||
"${MINGW_PACKAGE_PREFIX}-c-ares"
|
||||
"${MINGW_PACKAGE_PREFIX}-glib2"
|
||||
"${MINGW_PACKAGE_PREFIX}-gnutls"
|
||||
"${MINGW_PACKAGE_PREFIX}-libgcrypt"
|
||||
"${MINGW_PACKAGE_PREFIX}-libilbc"
|
||||
"${MINGW_PACKAGE_PREFIX}-libmaxminddb"
|
||||
"${MINGW_PACKAGE_PREFIX}-libpcap"
|
||||
"${MINGW_PACKAGE_PREFIX}-libssh"
|
||||
"${MINGW_PACKAGE_PREFIX}-libxml2"
|
||||
"${MINGW_PACKAGE_PREFIX}-lz4"
|
||||
"${MINGW_PACKAGE_PREFIX}-minizip"
|
||||
"${MINGW_PACKAGE_PREFIX}-nghttp2"
|
||||
"${MINGW_PACKAGE_PREFIX}-opus"
|
||||
"${MINGW_PACKAGE_PREFIX}-pcre2"
|
||||
"${MINGW_PACKAGE_PREFIX}-qt6-base"
|
||||
"${MINGW_PACKAGE_PREFIX}-qt6-multimedia"
|
||||
"${MINGW_PACKAGE_PREFIX}-qt6-5compat"
|
||||
"${MINGW_PACKAGE_PREFIX}-snappy"
|
||||
"${MINGW_PACKAGE_PREFIX}-spandsp"
|
||||
"${MINGW_PACKAGE_PREFIX}-speexdsp"
|
||||
"${MINGW_PACKAGE_PREFIX}-zlib"
|
||||
"${MINGW_PACKAGE_PREFIX}-zstd")
|
||||
makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
|
||||
"${MINGW_PACKAGE_PREFIX}-ninja"
|
||||
"${MINGW_PACKAGE_PREFIX}-cc"
|
||||
"${MINGW_PACKAGE_PREFIX}-python"
|
||||
"${MINGW_PACKAGE_PREFIX}-qt6-tools"
|
||||
'git')
|
||||
provides=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
||||
conflicts=("${MINGW_PACKAGE_PREFIX}-${_realname}")
|
||||
source=("${_realname}"::"git+https://gitlab.com/wireshark/wireshark.git")
|
||||
sha256sums=('SKIP')
|
||||
|
||||
pkgver() {
|
||||
cd "${_realname}"
|
||||
|
||||
git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
|
||||
}
|
||||
|
||||
build() {
|
||||
mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
|
||||
|
||||
declare -a extra_config
|
||||
if check_option "debug" "n"; then
|
||||
extra_config+=("-DCMAKE_BUILD_TYPE=Release")
|
||||
else
|
||||
extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
|
||||
fi
|
||||
|
||||
MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
|
||||
"${MINGW_PREFIX}"/bin/cmake.exe \
|
||||
-GNinja \
|
||||
-DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
|
||||
"${extra_config[@]}" \
|
||||
-DENABLE_WERROR=OFF \
|
||||
-DUSE_qt6=ON \
|
||||
-DENABLE_WINSPARKLE=OFF \
|
||||
../${_realname}
|
||||
|
||||
"${MINGW_PREFIX}"/bin/cmake.exe --build .
|
||||
}
|
||||
|
||||
check() {
|
||||
cd "${srcdir}/build-${MSYSTEM}"
|
||||
|
||||
"${MINGW_PREFIX}"/bin/cmake.exe --build . --target test
|
||||
}
|
||||
|
||||
package() {
|
||||
cd "${srcdir}/build-${MSYSTEM}"
|
||||
|
||||
DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install .
|
||||
|
||||
install -Dm644 "${srcdir}/${_realname}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
|
||||
}
|
Loading…
Reference in New Issue